技术资料：地图与数据库中有一字段相同，将它们关联起来

百花草 · 发表于 2009-11-15 19:26

技术资料：地图与数据库中有一字段相同，将它们关联起来
下列代码实现了类似地理匹配的功能。即TAB与DataBase中有一字段相同，将二者关联起来。（采用ODBC，DAO，ADO三种方式）

Private Sub cmdCustom_Click()
'Add the single layer
Map1.Layers.RemoveAll
Map1.Layers.Add App.Path & "\import.tab"
'make the map look nice for the sample data
Map1.DisplayCoordSys = Map1.NumericCoordSys
Map1.Title.Visible = False
Map1.Bounds = Map1.Layers.Item("import").Bounds
Map1.Zoom = Map1.Zoom * 2
Clickable (True)
End Sub
Private Sub cmdQuit_Click()
End
End Sub

Private Sub Command1_Click()
Dim ds As MapXLib.Dataset
Dim flds As New MapXLib.Fields
'requires reference to: "MapX ODBC Dataset Engine Library"
'and an ODBC DSN named import needs to be linked to import.mdb
Dim parm As New ODBCQueryInfo
parm.SqlQuery = "Select * from table1"
parm.DataSource = "import" 'DSN pointing to Mapstats.mdb
parm.ConnectString = "ODBC;"
' Get the relevant fields that'll come from DB
flds.Add "DB1", "DB1", miAggregationIndividual, miTypeString
flds.Add "DB2", "DB2byODBC", miAggregationIndividual, miTypeString
'Make Dataset
Set ds = Map1.Datasets.Add(miDataSetODBC, parm, "importODBC", "DB1", , "import", flds)
'make the theme
ds.Themes.Add miThemeAuto
Clickable (False)
End Sub

Private Sub Command2_Click()
Dim ds As MapXLib.Dataset
Dim flds As New MapXLib.Fields
'requires reference to: "Microsoft DAO Object Library"
Dim db As Database
Dim rs As Recordset
'open Database and recordset
Set db = DBEngine.Workspaces(0).OpenDatabase(App.Path & "/import.mdb")
Set rs = db.OpenRecordset("table1")
'define the fields
flds.Add "DB1", "DB1", miAggregationIndividual, miTypeString
flds.Add "DB2", "DB2byDAO", miAggregationIndividual, miTypeString
'add the dataset
Set ds = Map1.Datasets.Add(miDataSetDAO, rs, "importDAO", "DB1", , "import", flds)
'make theme and close out
ds.Themes.Add miThemeAuto
rs.Close
db.Close
Clickable (False)
End Sub

Private Sub Command3_Click()
Dim ds As MapXLib.Dataset
Dim flds As New MapXLib.Fields
'requires reference to Microsoft ActiveX Data Objects Library
Dim rs As New ADODB.Recordset
Dim Conn As New ADODB.Connection
Conn.Open (&quot

rovider=Microsoft.Jet.OLEDB.4.0;" & "Data Source=" & App.Path & "\import.mdb")
rs.CursorLocation = adUseClient
rs.Open "SELECT * FROM table1 ", Conn
'define the fields
flds.Add "DB1", "DB1", miAggregationIndividual, miTypeString
flds.Add "DB2", "DB2byADO", miAggregationIndividual, miTypeString
'add dataset
Set ds = Map1.Datasets.Add(miDataSetADO, rs, "importADO", "DB1", , "import", flds)
'make theme
ds.Themes.Add miThemeAuto
Clickable (False)
End Sub

Private Sub Form_Load()
Clickable (False)
End Sub

Public Sub Clickable(ByVal b As Boolean)
Command1.Enabled = b
Command2.Enabled = b
Command3.Enabled = b
End Sub
--------------------------------------------------------------------------------

fugangxx · 发表于 2021-12-19 14:53

谢谢分享

49130 · 发表于 2022-1-4 09:43

地图与数据库中有一字段相同

jxqkd123 · 发表于 2025-1-8 10:33

探矿者件可以提高矿体的命中率，减少找矿的成本和难度，主要功能：数据管理、二维制图、三维建模、储量估算、三维立体预测等，有需要免费试用可以联系负责人邓帅15377311476（微信同号），软件针对单位或者企业试用，不面向个人试用

技术资料：地图与数据库中有一字段相同，将它们关联起来

精华勋章

宣传勋章

爱心勋章

组织勋章

地信元老

灌水勋章

荣誉会员勋章

活跃勋章

贡献勋章